New Sansa Fuze+ Theme (SND v1.0) (Uploaded 10/14/2012)

[xpmule]

I deleted my previous comments here now that i finished the theme.

Sansa Fuze+ Seek & Destroy - Rockbox Theme v1.0


(right click view image for larger size)

Here is the download link.
http://www.multiupload.nl/UO48HHEQZC

This zip file (1.13mb) includes.
an SBS, WPS, FMS, Icons, Icons Config, Backdrop + Custom Graphics.
Also inside the .zip is PNG's files for all the BMP's
Oh and a custom font from the AA Font pack download. (Ubuntu 18 Bold)

I tested using 32bit bmps and i can't see any difference with image comparison tools
so i created them all at 24bits. The icon set is using the same license i'm pretty sure
and i included the license.txt file from the original icons author (For Glyphish icons)
The status bar icons are created myself with Adobe Fireworks.

Lastly If anyone wants to use any of this theme go ahead and do what ever ya want
Any feedback is welcome too

[[Saint]]

Nuts to what anyone else thinks...

Do you think it is worth submitting? If so, go for it.


[Saint]

[xpmule]

i figured that would be the response lol (makes sense)
the problem is i keep seeing things i can do to improve it..
and i for sure want to test various things on it etc
For one thing testing in the daylight outside is smart
because the device can be hard to see in sunlight
Doing this has driven the changes i made in the last couple days.

I also created a new shuffle icon so now its a 2 image tile (on/off)
rather than having a default icon embedded in the background. (like other themes i seen)

Code: [Select]

%xl(D,shuffle.bmp,0,0,2)
%?ps<%xd(Da)|%xd(Db)>

I'm trying to that for the repeat tile icon but it didn't work so I think what
i need to do is create some conditional scripting so it shows a default image
again rather than having the default embedded in the background..
It looks better that way when seeing the wps backdrop loading / exiting
I did that for my transparent/gradient bar behind the icons
(made it load dynamically rather than background embedded)
But the problem with that is the Text in the clock (text+image viewport limitation)
that worked but the background behind the clock was forced transparent
when it should have had a loaded image behind it (i seen a note saying we can't do that)

I changed the progress bar so it looks like pieces by using the purple/pink color(255,0,255)
If people don't know that is common on computers to specify any area using that color will
become transparent, the rockbox wiki says there is a pure cyan foreground variant too but
I'm not sure if that would be of any use to me. Anyway what i did was take my wide gradient bar
and i painted in pink stripes every 2 pixels wide so the bar now looks like many small images.
(see picture lol)


I've also tuned the icons so more so they are more consistent looking size / coloring etc

Also i dropped the left and right album art borders considering it won't look cool for artwork below 220px

Shifted the skull in the main backdrop up higher because i added it to the wps screen.
Thats the nice thing about working with png's i can save the source and drag around
text and overlays etc.

And lastly I'm making this long winded speel so it can give other people like me *New to this
some ideas or whatever.. I'm sure most people in here have been at this for ages and some are obviously very talented artists !

[amayer]

Code: [Select]

%xl(D,shuffle.bmp,0,0,2)
%?ps<%xd(Da)|%xd(Db)>

I'm trying to that for the repeat tile icon but it didn't work so I think what
i need to do is create some conditional scripting so it shows a default image
again rather than having the default embedded in the background..

Did you change out the Identifier used for the image?
ie.

Code: [Select]

%xl(E,repeat.bmp,0,0,5)
%?mm<%xd(Ea)|%xd(Eb)|%xd(Ec)|%xd(Ed)|%xd(Ee)>

if not could you paste the code that didnt work?

[cereal_killer]

I wanted to see if anyone thinks this is worth submitting.

I don't' have a fuze+, but I think it's totally worth submitting. Nice work amayer.

Big up,

c_k

[amayer]

Nice work amayer.

It is actually xpmule who is doing the theme. Im just trying to help with the coding part. I do make themes, but mine are for the iPod video.

[cereal_killer]

oh sorry mixed up the nicknames *lol*

[xpmule]

i figured out the coding part mentioned and i finished making changes to the theme
and i don't wanna brag but i think it looks pretty tight
The last thing I'm doing is converting the tango icons, i'm not happy with them all
needed to find a work around for the fact that Adobe Fireworks does not handle
32bit bmp's at all lol
So what i have done is use Infranview to pump out the 24bit version with alpha channel
and use fireworks with that and i don't see any difference really in the icon set
between 24 and 32bit under ultra zooming in (3200x) so i'm just gonna create 24bit icons

I'm going to post the code snippet i used for the shuffle and repeat icons
improved i think over the default theme because now you won't have to mess around
adding a default icon into the backdrop it can simply be apart of the strip with the others
i tested this a lot and it works perfect..

shuffle code

Code: [Select]

%xl(D,shuffle.bmp,0,0,2)
%V(125,4,16,11,-)
%?ps<%xd(Da)|%xd(Db)>

repeat code

Code: [Select]

%xl(E,repeat.bmp,0,0,5)
%V(155,3,11,13,-)
%?mm<%xd(Ea)|%xd(Eb)|%xd(Ec)|%xd(Ed)|%xd(Ee)>

changes coordinates of course

Anyways i have made endless tweaks to the icons etc but i think there done
and i added the strip of icons from the WPS screen to the main screen now too
and the radio screen looks fine i don't see any need for changes.
I will upload the theme soon and if anyone wants to use any part of it for any reason
i would be flattered and happy to share ..I decided to call the theme Seek 'n Destroy
because the skull in the backdrop was released a looooong time ago by the group
SND (Seek N Destroy) a software reverse engineering web group. few people know where the
skull image comes from but its used widely across the net for many years (smokeskull.gif)
A lot of people over the years have used the picture as an avatar on web sites.

Here is the final look of it (except i may change the Tango Icon set a bit ?)
(right click view image etc.. to see bigger pic)


I have always made my mp3 collection album art a minimum of 220x220px because that was to make sure my album covers were big enough for the sansa fuze+ default firmware so again for this theme you need album art for your files at least 220x220.

I've gone to extreme lengths to verify everything was aligned properly
although i don't know how this screendump feature works yet.. I've been simply hitting
my "Print Screen" key and pasting into Fireworks the screenshot.
And if anyone wants the Simulator picture seen in my pictures i uploaded here ya go..
http://www.multiupload.nl/W20Z4MNAZ7
just extract this new .bmp over top of the old one in your simulator folder.

Lastly i have read the Theme guidelines and made sure my theme adheres to the license.
And when i submit i will add the png's for the bmp's in case people want to tweak the theme to their liking. for example someone could tap on the Rockbox text on the png and delete and re-save the bmp if they did not like/want that part etc.

[xpmule]

edit:
I moved the preview images to the first comment.

Below is a preview of the new Icon set based on free/public set called Glyphish
columns 1 & 2 are UI icons and column 3 is the viewers icons.


edit:
Version 1 uploaded now.

I uploaded the whole theme but I don't know if I can submit the zip file with the stuff i have in it currently ?
I'm guessing i should remove the PNG's first. Also is it ok for me to submit a theme zip
with that AA font inside ? (came from the AA font pack download @ Rockbox.org)

[amayer]

The system wont let you upload a theme that has fonts from the fonts pack in it. you just have to put something like "REQUIRES suchandsuch.fnt" in the comment.

you should try and keep the stuff in a theme zip file to the stuff you actually need in the font. some people unzip the theme right onto their device and dont look at it. so if you have extra stuff in there your just taking up space on someones player.

[xpmule]

ya i was thinking the same about extra files
and thanks for tips.
now that i got an answer about the fonts and stuff
I think I will try and pack it up and submit the theme
but with some files removed etc

I've had more ideas for this theme and i'm tempted to make changes
to the radio screen but it was getting a bit stupid how many times
i kept making changes lol
next time i'll start a new theme and go from there.
In case i forgot to mention the FMS ? It's the same as the normal one
except i added the strip of custom status icons at the top.
Next time i think i'd change that up a bit..

i was also considering uploading the icon set on its own too
but i don't know if its too useful for other themes
with a dark grey background and small size (16x16)
Post Merge: October 17, 2012, 04:42:59 PMyup i have and thanks.
the zip i posted in this topic i believe follows all the guidelines
*except for maybe the extra .png images and the font.

anyway i'll try and get this done now i keep putting it off lol
added to database now. also i first tried to add the theme with the font removed
but it said it was required so i put it back in and the submission went through ok.

[amayer]

if you havent already i would read this

[zezayer]

Thanks for the theme, has become my default for my fuze+.

Here is a copy of a custom fms I have made for your theme, feel free to add it to the package / improve it should you want to. I tried to put a stereo|mono option in the top right corner, but couldn't get it to work so just gave up.

- I have also modified your playmode tags to include play and pause symbols during recording and fm modes, as currently they show the rewind symbol for this. (I have done this on my wps/sbs's aswell)

Code: [Select]

# - Play Mode
%V(180,3,12,13,-)
%?mp<%xd(Fa)|%xd(Fb)|%xd(Fc)|%xd(Fd)|%xd(Fe)|%xd(Fb)|%xd(Fc)|%xd(Fb)|%xd(Fc)>

The code is based on your wps but other parts have been robbed from a number of other fms / wps's.

n.b. copy the code into seek_n_destroy.fms

Code: [Select]

%Vi(-,0,20,-,-,1)

# - Images
%xl(A,lock.bmp,0,0,2)
%xl(B,battery.bmp,0,0,22)
%xl(C,volume.bmp,0,0,20)
%xl(D,shuffle.bmp,0,0,2)
%xl(E,repeat.bmp,0,0,5)
%xl(F,playmode.bmp,0,0,5)

# - Time (w/ brighter font color)
%V(13,0,66,18,-)%Vf(999999)%Vb(000000)
%?ca<%al%?cf<%cH:%cM|%cl:%cM>|00:00>

# - Lock
%V(56,3,21,13,-)
%?mh<%xd(Aa)|%xd(Ab)>

# Volume
%V(91,4,20,11,-)
%?pv<%xd(Ca)|%xd(Cb)|%xd(Cc)|%xd(Cd)|%xd(Ce)|%xd(Cf)|%xd(Cg)|%xd(Ch)|%xd(Ci)|%xd(Cj)|%xd(Ck)|%xd(Cl)|%xd(Cm)|%xd(Cn)|%xd(Co)|%xd(Cp)|%xd(Cq)|%xd(Cr)|%xd(Cs)|%xd(Ct)>

# - Shuffle
%V(125,4,16,11,-)
%?ps<%xd(Da)|%xd(Db)>

# - Repeat
%V(155,3,11,13,-)
%?mm<%xd(Ea)|%xd(Eb)|%xd(Ec)|%xd(Ed)|%xd(Ee)>

# - Play Mode
%V(180,3,12,13,-)
%?mp<%xd(Fa)|%xd(Fb)|%xd(Fc)|%xd(Fd)|%xd(Fe)|%xd(Fb)|%xd(Fc)|%xd(Fb)|%xd(Fc)>

# - Battery
%V(205,4,20,11,-)
%?bp<%ar%?bc<%xd(Ba)|%xd(Bb)>|%?bl<|%xd(Bc)|%xd(Bd)|%xd(Be)|%xd(Bf)|%xd(Bg)|%xd(Bh)|%xd(Bi)|%xd(Bj)|%xd(Bk)|%xd(Bl)|%xd(Bm)|%xd(Bn)|%xd(Bo)|%xd(Bp)|%xd(Bq)|%xd(Br)|%xd(Bs)|%xd(Bt)|%xd(Bu)|%xd(Bv)>>

# - Backdrop
%X(wps_backdrop.bmp)

# Scan/Preset mode
#
%V(3,27,94,-,-) %Vf(ffffff)
%?tm<Scan|Preset>
%?tm<|%?if(%Tc,=,0)<%t(1)No Preset;%t(1) |%Ti/%Tc>>

%V(0,90,-,-,-) %Vf(ffffff)
%ac Rockbox Radio Player

# Signal Strength
#
%V(0,180,-,-,-) %Vf(ffffff)
%ac%Sx(Signal strength:) %tr dBuV

# RDS Data
#
%V(1,120,238,60,-) %Vf(ffffff)
%s%ac%?tt<%?ty<%ty|%?Tn<%Tn|>>|%?ty<%ty|%?Tn<%Tn|searching...>>>
%s%ac%?tz<%tz|>

# - Frequency
%V(14,238,213,16,-)%Vf(999999)
%al%ta%ac%tf MHz%ar%tb
 	
# - Progress Bar
%V(10,256,220,8,1)
%pb(0,0,220,8,ProgressFront.bmp)

[zezayer]

and here is my modified sbs which now has a now playing screen for music and fm at the bottom (like with lebellium Samsung-like)

- You also need to copy seek_n_destroy.bmp from .rockbox/backdrops to .rockbox/wps/seek_n_destroy for the background change to work

Code: [Select]

#%Vi(-,0,20,-,-,1)

# - Images
%xl(A,lock.bmp,0,0,2)
%xl(B,battery.bmp,0,0,22)
%xl(C,volume.bmp,0,0,20)
%xl(D,shuffle.bmp,0,0,2)
%xl(E,repeat.bmp,0,0,5)
%xl(F,playmode.bmp,0,0,5)

# - Time (w/ brighter font color)
%V(13,0,66,18,-)%Vf(999999)%Vb(000000)
%?ca<%al%?cf<%cH:%cM|%cl:%cM>|00:00>

# - Lock
%V(56,3,21,13,-)
%?mh<%xd(Aa)|%xd(Ab)>

# Volume
%V(91,4,20,11,-)
%?pv<%xd(Ca)|%xd(Cb)|%xd(Cc)|%xd(Cd)|%xd(Ce)|%xd(Cf)|%xd(Cg)|%xd(Ch)|%xd(Ci)|%xd(Cj)|%xd(Ck)|%xd(Cl)|%xd(Cm)|%xd(Cn)|%xd(Co)|%xd(Cp)|%xd(Cq)|%xd(Cr)|%xd(Cs)|%xd(Ct)>

# - Shuffle
%V(125,4,16,11,-)
%?ps<%xd(Da)|%xd(Db)>

# - Repeat
%V(155,3,11,13,-)
%?mm<%xd(Ea)|%xd(Eb)|%xd(Ec)|%xd(Ed)|%xd(Ee)>

# - Play Mode
%V(180,3,12,13,-)
%?mp<%xd(Fa)|%xd(Fb)|%xd(Fc)|%xd(Fd)|%xd(Fe)|%xd(Fb)|%xd(Fc)|%xd(Fb)|%xd(Fc)>

# - Battery
%V(205,4,20,11,-)
%?bp<%ar%?bc<%xd(Ba)|%xd(Bb)>|%?bl<|%xd(Bc)|%xd(Bd)|%xd(Be)|%xd(Bf)|%xd(Bg)|%xd(Bh)|%xd(Bi)|%xd(Bj)|%xd(Bk)|%xd(Bl)|%xd(Bm)|%xd(Bn)|%xd(Bo)|%xd(Bp)|%xd(Bq)|%xd(Br)|%xd(Bs)|%xd(Bt)|%xd(Bu)|%xd(Bv)>>

#New code

%?mp<%VI(Z)|%VI(X)|%VI(X)|%VI(X)|%VI(X)|%VI(Z)|%VI(Z)|%VI(X)|%VI(X)|>
%Vi(X,5,20,230,220,-)%Vf(ffffff)
%Vi(Z,5,20,230,-,-)%Vf(ffffff)

%xl(stop,seek_n_destroy.bmp,0,0)
%xl(play,wps_backdrop.bmp,0,0)
#
%V(0,0,-,-,-)%VB
%?mp<%xd(stop)|%xd(play)>

%V(0,253,-,60,-)
#%?mp<Stop|Play|Pause|Ffwd|Rew|Rec|Rec pause|FM|FM pause>
%?mp<|%Vd(meta)%Vd(meta)%Vd(meta)%Vd(meta)%Vd(progress)|%Vd(meta)%Vd(meta)%Vd(meta)%Vd(meta)%Vd(progress)|%Vd(meta)%Vd(meta)%Vd(meta)%Vd(meta)%Vd(progress)|%Vd(meta)%Vd(meta)%Vd(meta)%Vd(meta)%Vd(progress)|||%Vd(radio)%Vd(radio)%Vd(progress)|%Vd(radio)%Vd(radio)%Vd(progress)>

# - Progress Bar
%Vl(progress,10,256,220,8,1)
%pb(0,0,220,8,ProgressFront.bmp)


#Meta x4

# - Track Time 
%Vl(meta,14,238,213,16,1)%Vf(999999)
%al%pc%ac%pp/%pe%ar%pt

# - Artist
%Vl(meta,0,264,240,18,1)
%s%ac%?ia<%ia|%?d(2)<%d(2)|%(root%)>>

# - Album
%Vl(meta,0,282,240,18,1)
%s%ac%?id<%id|%?d(1)<%d(1)|%(root%)>>

# - Title
%Vl(meta,0,300,240,18,1)
%s%ac%?it<%it|%fn>

#Radio

# - Frequency
%Vl(radio,14,238,213,16,-)%Vf(999999)
%al%ta%ac%tf MHz%ar%tb

# - Station
%Vl(radio,0,282,240,18,1)
%s%ac%?tt<%?ty<%ty|%?Tn<%Tn|>>|%?ty<%ty|%?Tn<%Tn|searching...>>>
%s%ac%?tz<%tz|>

[cereal_killer]

I'd love to have this theme on an ipod video too...